Pengenalan Properties, Method dan Event
Form adalah Object Visual Basic pertama yang harus kita kenali. Hal ini di sebabkan karena hampir semua aplikasi Visual Basic menggunakan satu Form atau lebih. Control adalah object VB yang dapat di letakan dalam Form.
Form dan object-object dalam VB dapat kita analogikan dengan manusia, di mana setiap manusia memiliki cirri khas tertentu, misalnya seperti tinggi badan, gemuk kurus dan sebagainya maka object dalam VB juga memiliki karakteristik yang di kenal dengan nama Properties. Jika manusia bisa melakukan tindakan-tindakan seperti menghapus, berjalan dan sebagainya maka object juga memiliki tindakan yang di sebut dengan methods seperti Move, PaintPicture, CLS, Print. Manusia dapat bereaksi terhadap suatu event tertentu maka object juga dapat, hal ini di kenal dengan nama Event, misalnya saat Mouse diklik, key board di tekan dan lain sebagainya.
A. Properties Standard
Setiap Object dalam VB memiliki banyak sekali properties, tetapi biasanya properties itu juga di miliki oleh object lain sehingga jika kita sudah menguasai salah satu object, untuk mempelajari object lain akan menjadi lebih mudah. Berikut ini akan di bahas properties-properties standard yang ada hamper di setiap object dalam VB.
Properties Left, Top, Width dan Height
Hampir semua object yang dapat di lihat memiliki properties ini di karenakan properties ini di gunakan untuk menunjukan letak dan ukuran dari object tersebut.
Top dan left di gunakan untuk menentukan posisi dari object, dimana Top adalah posisi sumbu Y control dalam container, dimana semakin besar nilai Top maka posisi object makin ke bawah. Properties Left di gunakan untuk menentukan posisi object pada sumbu X dalam container di mana makin besar nilai Left maka posisi Object akan makin ke kanan. Container adalah sebuah object yang dapat menampung object lainnya seperti object Form atau object Frame.
Properties Width dan Height di gunakan untuk menentukan ukuran dari object di mana width merupakan lebar dan height merupakan tinggi dari object. Ukuran yang di gunakan adalah twips dimana1440 twips = 1 inchi atau 567 twips = 1 cm. Pada beberapa object properties Left, Top, Width dan Height hanya bisa di baca dan tidak bisa diganti seperti pada object combo box, dimana Height-nya di pengaruhi oleh font yang di gunakan oleh object tersebut.
Contoh Programnya :
Private Sub Command1_Click()
‘Memindahkan Posisi Picture1 ke kiri
Picture1.Left = Picture1.Left – 20
End Sub
Private Sub Command2_Click()
‘Memindahkan Posisi Picture1 ke bawah
Picture1.Top = Picture1.Top + 20
End Sub
Private Sub Command3_Click()
‘Memindahkan Posisi Picture1 ke atas
Picture1.Top = Picture1.Top - 20
End Sub
Private Sub Command4_Click()
‘Memindahkan Posisi Picture1 ke kanan
Picture1.Left = Picture1.Left + 20
End Sub
Private Sub Command5_Click()
‘Mengurangi lebar dan tinggi Picture1
Picture1.Width = Picture1.Width - 10
Picture1.Height = Picture1.Height - 10
End Sub
Private Sub Command6_Click()
‘Menambahkan lebar dan tinggi Picture1
Picture1.Width = Picture1.Width + 10
Picture1.Height = Picture1.Height + 10
End Sub
Dalam Program ini saat user menekan Command arah maka Picture1 akan bergerakn mengikuti arah command tersebut. Jika user menekan Kecil maka program akan mengurangi width dan height dari picture1 dan sebaliknya jika user menekan command besar.
Properties ForeColor dan BackColorPropeperties ForeColor dan BackColor mempengaruhi warna dari tulisan dan background dari sebuah object. Pada beberapa object, properties ini di pengaruhi oleh properties lain misalnya pada object label properties BackColor tidak akan berguna jika properties BackStyle-nya bernilai 0-Transparent.
Saat memilih dalam properties window maka kita dapat memilih warna dari antara Pallete ataupun System. Warna dari System di pengaruhi oleh system, misalnya jika kita menggunakan styleXp atau kita merubah-rubah warna standard sytem maka warna tersebutlah yang akan tampil.
Gambar Pilihan Warna System dan Warna Palette
Kita juga dapat memberikan warna dengan menggunakan metode RGB, QBCOLOR ataupun dengan HeksaDesimal.
Daftar Warna
| Konstanta | Nilai Heksa | Deskripsi |
| vb3DDKShadow | &H80000015 | Darkest shadow |
| vb3Dface | &H8000000F | Dark shadow color for 3-D display elements |
| vb3Dhighlight | &H80000014 | Highlight color for 3-D display elements |
| vb3Dlight | &H80000016 | Second lightest of the 3-D colors after vb3Dhighlight |
| vb3Dshadow | &H80000010 | Color of automatic window shadows |
| vbActiveBorder | &H8000000A | Active window border color |
| vbActiveTitleBar | &H80000002 | Active window caption color |
| vbActiveTitleBarText | &H80000009 | Text color in active caption, size box, scroll bar arrow box |
| vbApplicationWorkspace | &H8000000C | Background color of multiple-document interface (MDI) applications |
| vbButtonFace | &H8000000F | Face shading on command buttons |
| vbButtonShadow | &H80000010 | Edge shading on command buttons |
| vbButtonText | &H80000012 | Text color on push buttons |
| vbDesktop | &H80000001 | Desktop color |
| vbGrayText | &H80000011 | Grayed (disabled) text |
| vbHighlight | &H8000000D | Background color of items selected in a control |
| vbHighlightText | &H8000000E | Text color of items selected in a control |
| vbInactiveBorder | &H8000000B | Inactive window border color |
| vbInactiveCaptionText | &H80000013 | Color of text in an inactive caption |
| vbInactiveTitleBar | &H80000003 | Inactive window caption color |
| vbInactiveTitleBarText | &H80000013 | Text color in inactive window caption, size box, scroll bar arrow box |
| vbInfoBackground | &H80000018 | Background color of ToolTips |
| vbInfoText | &H80000017 | Color of text in ToolTips |
| vbMenuBar | &H80000004 | Menu background color |
| vbMenuText | &H80000007 | Text color in menus |
| vbScrollBars | &H80000000 | Scroll bar gray area color |
| vbTitleBarText | &H80000009 | Text color in active caption, size box, scroll bar arrow box |
| vbWindowBackground | &H80000005 | Window background color |
| vbWindowFrame | &H80000006 | Window frame color |
| vbWindowText | &H80000008 | Text color in windows |
Properties Font
Properties Font biasanya dimiliki oleh object-object yang dapat menampilkan string. Properties Font terdiri dari properties Name, Size, Bold, Italic, Underline dan Strikethrough.
Contoh Sintaksnya
‘Mengganti Nama Font
Me.Font.Name = ”Arial”
‘Mengganti Ukuran Font
Me.Font.Size = 14
‘Menggarisbawahi Font
Me.Font.Underline = true
‘Membuat Font suatu object sama dengan object lain
‘dan font tersebut akan ikut berganti jika font yang
‘di ikutinya juga berganti
Set object1.font = object2.font
Saat mendesain kita bisa mengklik Font dalam property window untuk menampilkan Font Dialog.
Gambar Font Window
Dalam perancangan di Run Time, penggantian Font dengan nilai yang salah tidak akan menampilkan error, tetapi VB akan mengubah nilainya dengan yang paling mungkin untuk ukuran dan tidak menentu untuk nama Font.
Properties Caption dan Text
Caption adalah properties yang biasanya terdapat dalam suatu object yang memiliki nilai string yang tidak dapat di edit ataupun di blok oleh user. Text adalah properties yang biasanya terdapat pada suatu object yang dapat di tulisi string oleh user atau user dapat memblok nilai string tersebut.
Biasanya dalam caption kita dapat menggunakan tanda & (ampersand) untuk mebuat object tersebut mendapat focus jika kita menekan tombol Alt + tombol setelah tanda &.
Umumnya jika sebuah object mendukung properties Text maka ia juga mendukung selText, SelStart dan SelLength yang memengaruhi Text yang di blok.
Contoh Program :
‘Event ini berjalan saat user mengubah nilai Scroll Di Frame BackColor
Private Sub Back_Color_Change(Index As Integer)
Me.Label1.BackColor = RGB(Me.Back_Color(0).Value, Me.Back_Color(1).Value, Me.Back_Color(2).Value)
End Sub
‘Event ini berjalan saat user mengubah nilai Scroll Di Frame BackColor
Private Sub Back_Color_Scroll(Index As Integer)
Me.Label1.BackColor = RGB(Me.Back_Color(0).Value, Me.Back_Color(1).Value, Me.Back_Color(2).Value)
End Sub
Private Sub cboNama_Click()
Me.Label1.Font.Name = cboNama.Text
End Sub
Private Sub cboUkuran_Click()
Me.Label1.Font.Size = cboUkuran.Text
End Sub
Private Sub chkBold_Click()
Me.Label1.Font.Bold = Not Me.Label1.Font.Bold
End Sub
Private Sub chkItalic_Click()
Me.Label1.Font.Italic = Not Me.Label1.Font.Italic
End Sub
Private Sub chkStrikeThrought_Click()
Me.Label1.Font.Strikethrough = Not Me.Label1.Font.Strikethrough
End Sub
Private Sub chkUnderLine_Click()
Me.Label1.Font.Underline = Not Me.Label1.Font.Underline
End Sub
Private Sub cmdTampil_Click()
‘Melakukan Pengecekan apakah teks sudah di blok
‘Jika sudah maka panjangnya yeks yang di blok pasti>0
If Text1.SelLength = 0 Then
MsgBox “Tidak ada Teks Yang DiBlok”, vbCritical
Else
Label1.Caption = Text1.SelText
End If
End Sub
Private Sub Fore_Color_Change(Index As Integer)
Me.Label1.ForeColor = RGB(Me.Fore_Color(0).Value, _
Me.Fore_Color(1).Value, Me.Fore_Color(2).Value)
End Sub
Private Sub Fore_Color_Scroll(Index As Integer)
Me.Label1.ForeColor = RGB(Me.Fore_Color(0).Value, _
Me.Fore_Color(1).Value, Me.Fore_Color(2).Value)
End Sub
Private Sub Form_Load()
‘menghilangkan tampilan control file
File1.Visible = False
‘membuat control file1 mencari file dengan ext .ttf
File1.Pattern = “*.ttf”
‘membuat control file1 mencari di dir D:\Windows\Font
File1.Path = “D:\WINDOWS\FONTS”
Dim i As Integer
‘Memasukan nilai-nilai yang ada di file1 ke dalam
‘control cboNama dan menghilangkan
‘extensionnya dengan cara mengurangi panjang data
‘sebanyak 4 karakter dari blkang
For i = 0 To File1.ListCount - 1
Me.cboNama.AddItem Mid(File1.List(i), 1, _
Len(File1.List(i)) - 4)
Next i
‘membuat CboNama menunjuk index pertama
Me.cboNama.ListIndex = 0
For i = 4 To 18
Me.cboUkuran.AddItem i
Next i
‘Memberikan nilai Fore_Color untuk masing2x object
‘array
For i = 0 To 2
Me.Fore_Color(i) = 255
Next i
Me.cboUkuran.ListIndex = 5
‘Membuat Font text1 selalu mengikuti Font label1
Set Text1.Font = Label1.Font
‘ Memanggil Prosedur-prosedur
cboNama_Click
cboUkuran_Click
Back_Color_Scroll 1
Fore_Color_Change 1
Refresh
End Sub
Private Sub Text1_Change()
‘ Membuat nilai label1 sama dengan text1
Label1.Caption = Text1.Text
End Sub
Gambar Contoh 2
Properties Parents dan Container
Properties Parents adalah properties yang hanya terdapat pada keadaan Run Time, yaitu pada saat program di jalankan. Dengan Parent dapat di beritahukan pada form bahwa control tersebut berada dalam form itu.
Properties Container juga merupakan properties Run Time Only. Ia memberitahukan pada Container bahwa control tersebut berada Container itu. Kita dapat memindahkan sebuah object dari satu container ke container lainnya dengan cara :
Set Nama_Control.Container = Nama_Container
Contoh :
‘Memindahkan Command1 ke dalam picture1 dan
‘meletakannya di pojok kiri atas container
Set Command1.Container = Picture1
Command1.Top = 1
Command1.Left = 1
Properties Enabled dan Visible
Semua control dalam VB secara default memiliki properties True untuk Enabled dan Visible. Tetapi, karena beberapa alasan kadang-kadang kita ingin hanya menampilkan suatu object tanpa bisa di gunakan oleh user, atau kita juga ingin menggunakan suatu object tanpa memperlihatkannya kepada user.
Properties Enabled = false dapat digunakan untuk membuat control tersebut bebas dari pengaruh user, tetapi control tersebut tetap dapat di pengaruhi oleh program melalui proses pengkodean. Properti Visible = false dapat di gunakan untuk menyembunyikan sebuah control sehingga tidak terlihat oleh user.
Properties hWnd
Properties hWnd termasuk properties yang bersifat Run Time Only. Selain itu ia juga merupakan Read Only Properties yang hanya bisa di baca dan tidak bisa di tulis. hWnd memberikan nilai integer 32 bit yang di berikan windows untuk mengindentifikasi suatu control. Nilai dari hWnd ini akan hanya di gunakan pada penggunaan VB API .
Kontrol dari VB dapat dibedakan menjadi dua, yaitu standard dan windowless. Contohnya adalah PictureBox (standard) dan Image (windowless). Walaupun keliahatannya ke dua control itu sama, tetapi mereka sungguh berbeda.
Saat kita meletakan suatu control standard ke dalam form, VB meminta OS untuk membuat sebuah instance, sehingga OS memberikan nilai kepada control tersebut yang berupa nilai hWnd. Saat control itu menerima event, control tersebut akan melakukan fungsi API dan lalu memberitahukan OS control mana yang dipengaruhi.
Kontrol windowless di lain pihak tidak melakukan tersebut, dan hanya membutuhkan VB untuk mengaturnya. Sehingga control windowless adalah control yang tidak mengandung property hWnd karena ia tidak berinteraksi dengan OS, walaupun terkadang ada control standard yang tidak memberikan properties hWnd dengan beberapa alasan.
Kontrol standard memakan memory dan resource lebih banyak daripada control windowless dengan contoh perbandingan form yang mengandung 100 Picture Box akan 10 kali lebih lambat daripada form yang mengandung 100 image control.
Properties TabStop dan TabIndex
Jika sebuah control dapat menerima focus maka control tersebut pasti memili dua properties ini. Kontrol windowless tidak akan memiliki ke dua properties ini karena mereka tidak akan pernah mendapatkan focus.
TabStop memberikan keterangan apakah dengan menekan tab, focus dapat diberikan kekontrol tersebut. TabIndex memberikan keterangan tentang urutan keberapakah suatu konrol akan mendapat giliran mendapat fokus.
Properties MousePointer dan MouseIcon
Properties ini mempengaruhi bentuk dari Cursor Mouse saat berada di atas sebuah control. VB memberikan cara yang sangat flexible dalam memanajemen bentuk mouse karena setiap form dan control dapat memberikan bentuk mouse yang berbeda.
Properties MousePointer digunakan untuk menentukan jenis mouse yang akan digunakan sedangkan properties MouseIcon digunakan untuk me-load Mouse Icon yang tidak terdapat dalam VB. Tetapi nilai dalam MousePointer-nya harus diganti dengan 99-vbCustom terlebih dahulu.
Berikut ini adalah contoh penggunaannya :
‘Contoh Mouse Pointer
‘Misalnya Program akan mengubah bentuk mouse menjadi CrossHair saat ada di ’picture Box
Picture1.MousePointer = vbCrosshair
MousePointer = vbDefault
‘Contoh Penggunaan MouseIcon
‘Kita ubah dulu MousePointer menjadi 99-vbCustom
MousePointer = vbCustom
‘Masukan alamat File .ico-nya
MouseIcon = LoadPicture(”D:\Program Files\Microsoft Visual _
Studio\VB98\graphics\icons\computer\msgbox01.ico”)
Properties Tag
Semua konrol memiliki Properties tag ini, karena properties ini berasal dari VB sehingga bahkan control ActiveX pun memilikinya. Properties yang berasal dari VB selain Tag adalah Index, Visible, TabStop, TabIndex, ToolTipText, HelpContextID, dan WhatsThisHelpID.
Fungsi Properties Tag hanyalah untuk menyimpan data yang biasanya berhubungan dengan control yang memiliki Tag tersebut. Jadi Properties ini fungsi seperti variabel.
Properties Lainnya
Properties Value biasanya di gunakan untuk menyimpan nilai dari suatu control. Misalnya checkbox, CommandButton, OptionButton dan scrollbar.
Properties Index digunakan untuk memberikan petunjuk no array bagi sebuah control. Jika sebuah control bukan array maka nilai index-nya adalah kosong.
Properties BorderStyle menentukan apakah sebuah control menggunakan Border atau tidak.
Properties ToolTips digunakan untuk mengisi kotak kuning kecil yang berisi petunjuk yang akan ditampilkan jika kita menunjuk sebuah control dengan pointer mouse selama waktu tertentu.
B. Method Standar
Hampir semua object dalam VB memiliki method. Method adalah sebuah fungsi atau prosedur yang akan dilakukan oleh sebiah object. Berbeda dengan properties, jumlah method tidaklah begitu banyak. Berikut ini adalah method-method setandar.
Move Method
Jika sebuah control mendukung properties Left, Top, Width, dan Heigh maka control tersebut juga akan memilki method Move. Move di gunakan untuk menggerakan atau mengganti ukuran sebuah control.
Sintaksnya : Control.Move Left, [Top], [Width], [Height]
Contoh Pengunaannya
‘Memindahkan Pic ke kiri atas
pic.Move 0, 0
‘Mengubah ukuran pic jadi 2 kali lipat
pic.Move Me.Left, , pic.Width * 2, pic.Height * 2
Penggunaan Method Move memiliki kecepatan dua kali lipat dari pada jika mengganti properties secara manual dan dia juga hanya memanggil event Resize satu kali saja walaupun keempat properties kita ganti semuanya.
Method Refresh
Method Refresh digunakan untuk membuat program berhenti untuk menyelesaikan tugas sebelumnya sebelum melanjutkan ke perintah berikutnya. Hal ini biasanya dilakukan pada PictureBox, ataupun label.
Sintaksnya : Control.Refresh
Contoh Pengunaannya
Dim I as integer
Dim Pros as Byte
for I = 1 to 10
‘Melakukan Peloadingan Gambar
pic.picture loadPicture(“D:\JoTampan” & I & “.jpg”)
‘Mebuat Gambar langsung ditampilkan
pic.refresh
‘Label menunjukan jumlah proses
pros= I * 10
LblPros.Caption = “Meload Gambar JoTampan” & _
I & “.jpg (” & Pros & “%)”
‘Membuat Nilai Proses Ditampilkan
LblPros.Refresh
Next I
Method SetFocus
Method ini digunakan untuk memberikan sebuah control focus, sehingga Control tersebut memanggil Event GotFocus. Method ini biasanya digunakan pada textbox.
Sintaksnya : Control.SetFocus
Contoh Pengunaannya
‘Saat User Menekan Tombol Submit
Private Sub cmdSubmit_Click()
‘Program Memeriksa apakah nama diisi
If txtNama.Text = “” Then
MsgBox “Nama Harus Disiisi”, vbCritical
txtNama.SetFocus
else
Msgbox “Pengisian sudah benar”, vbInformation
End If
End Sub
Method Zorder
Zorder digunakan untuk memindahkan letak sebuah control. Method ini menentukan apakah sebuah control berada di depan atau di belakang control lainnya.
Sintaksnya : Control.Zorder [1]
Jika tanpa menggunakan 1 maka control akan di detempatkan di depan control yang lain, sedangkan jika dengan 1 maka control akan dipindahkan ke belakang control yang lain.
Contoh Pengunaannya
‘Meletakan Label1 DiDepan
Private Sub Command1_Click()
Label1.ZOrder
End Sub
‘Meletakan Label1 diBelakang
Private Sub Command2_Click()
Label1.ZOrder 1
End Sub
C. Event Standar
Event dalam VB adalah suatu kejadian yang dapat mengakibatkan di jalankannya perintah-perintah program. Event di gunakan sebagai tempat menuliskan kode-kode pemrograman.
Event Click dan DoubleClick
Event click terjadi pada saat user mengklik suatu control, dan doubleClick terjadi saat user melakukan doubleClick. Event Click juga terjadi jika kita merubah nilai Value dari optionBox atau checkbox melalui kode pemrograman.
Event Change
Event Change terjadi pada saat user merubah nilsi Properties tertentu (umumnya properties Text) dari suatu Control Baik dengan di ketik maupun dengan kode. Event ini dimiliki oleh TextBox, ComboBox, DriveListBox, DirListBox dan PictureBox.
Event GotFocus dan LostFocus
Event GotFocus terjadi pada saat sebuah control mendapatkan focus dari user (diklik misalnya). Sedangkan LostFocus terjadi pada saat user memberikan focus kepada control lainnya.
Event KeyDown, KeyPress dan KeyUp
Event-event ini terjadi saat user menekan tombol keyboard dan lalu melepaskannya. Urutan Event ini adalah KeyDown yaitu saat user menekan tombol keyboard, setelah itu KeyPress yaitu pada saat Program menerjemahkan nilai tombol keyboard yang di tekan dengan kode ANSI, lalu terakhir adalah keyUp yaitu saat user melepaskan tombol KeyBoard.
Event KeyDown dan KeyUp memiliki dua buah Parameter yaitu keyCode dan Shift. KeyCode digunakan untuk memberikan nilai tombol yang ditekan, sedangkan shift menunjukan keadaan tombol Ctrl, Shift dan alt.
Contoh Penggunaan :
Private Sub Text1_KeyDown(KeyCode As Integer, _Shift As Integer)‘Pengecekan nilai Shift dilakukan dgn menggunakan And If Shift And vbShiftMask Then ' Shift key pressed End If If Shift And vbCtrlMask Then ' Ctrl key pressed End If If Shift And vbAltMask Then ' Alt key pressed End IfEnd SubPrivate sub Text1_KeyPress(KeyAscii As Integer) MsgBox "User pressed " & Chr$(KeyAscii)End SubEvent MouseDown, MouseMove dan MouseUp
Event MouseDown terjadi saat user menekan Salah satu tombol Mouse. MouseMove terjadi saat user menggerakan Mouse di atas control dan MouseUp terjadi saat user melepaskan tombol Mouse yang di tekan.
ContohProgramnya :
Private Sub Form_Load()
‘Membuat Form mampu melakukan Penggambaran Ulang
Me.AutoRedraw = True
End Sub
Private Sub Form_MouseDown(Button As Integer, _
Shift As Integer, X As Single, Y As Single)
Tampilkan Button, Shift, X, Y
End Sub
Private Sub Form_MouseMove(Button As Integer, _
Shift As Integer, X As Single, Y As Single)
Tampilkan Button, Shift, X, Y
End Sub
Private Sub Form_MouseUp(Button As Integer, _
Shift As Integer, X As Single, Y As Single)
Tampilkan Button, Shift, X, Y
End Sub
Sub Tampilkan(TombolMouse As Integer, _
Shift As Integer, X As Single, Y As Single)
Me.Cls
Me.Print “Posisi Tombol Mouse ada di (” _
& X & “,”; Y & “)”
If Not TombolMouse = 0 Then
Dim YangDiTekan As String
If TombolMouse = 1 Then
YangDiTekan = “Kiri”
Else
YangDiTekan = “Kanan”
End If
Me.Print “Tombol yang di tekan adalah” & _
” Tombol ” & YangDiTekan
End If
If Not Shift = 0 Then
If Shift = 1 Then
Me.Print “User Menekan Shift “
ElseIf Shift = 2 Then
Me.Print “User Menekan CTRL “
ElseIf Shift = 4 Then
Me.Print “User Menekan aLT “
End If
End If
Me.Refresh
End Sub
Tidak ada komentar:
Posting Komentar